რა არის CoCoA?

• CoCoA არის პროგრამა რიცხვების და მრავალწევრების გამოყენებით გამოთვლების ჩასატარებლად.
• ის უფასოა.
• ის მუშაობს მრავალ ოპერაციულ სისტემაზე.
• ის გამოიყენება მრავალი მკვლევარის მიერ, მაგრამ შეიძლება იყოს გამოსადეგი "მარტივი" გამოთვლებისთვის.

რა შეიძლება დავთვალოთ CoCoA-ს საშუალებით?

ძალიან დიდი მთელი რიცხვვები

უდიდესი "მანქანური მთელი რიცხვი" რაც შეგიძლიათ გამოიყენოთ 32-ბიტიან კომპიუტერზე არის 2^32-1, მაგრამ CoCoA-ს, მძლავრი GMP ბიბლიოთეკის საშუალებით , შეუძლია დათვალოს ისეთი დიდი რიცხვები როგორიცაა 2^300000: სცადეთ!

2^32-1; 

4294967295

2^64-1; 

18446744073709551615

რაციონალური რიცხვები

CoCoA ძალიან ზუსტია წილადებთან: ის არასდოს ამრგვალებს მათ! ანუ 1/3 ძალიან განსხვავდება რიცხვისგან 0.3333333333333

(1/3) * 3;

1

0.3333333333333 * 3;

9999999999999/10000000000000

მრავალწევრები

CoCoA მორგებულია მრავალწევრული გამოთვლებისთვის: მას შეუძლია გაამრავლოს, გაყოს, დაშალოს მამრავლებად, ...

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

წრფივი სისტემები

CoCoA-ს შეუძლია ამოხსნას წრფივი სისტემები. თქვენ მხოლოდ გჭირდებათ დაწეროთ ყველა განტოლება f = c მრავალწევრის სახით f - c. CoCoA-ს ასევე შეუძლია ამოხსნას მრავალწევრული სისტემები, მაგრამ ეს შედარებით რთულია და ამას ვიხილავთ შემდგომ. ახლა კი ამოვხსნათ

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

მაშასადამე ამონახსნია (z=21/5, x=-3/5, y=8/5)

არაუარყოფითი მთელი ამონახსნები

შეგიძლიათ იპოვოთ არაუარყოფითი მთელი რიცხვების სამეულები რომლებიც არიან შემდეგი განტოლებათა სისტემის ამონახსნები?

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

ინტერპრეტაციაა ის, რომ არსებობს ნხოლოდ ოთხი ამონახსნი: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

მაგალითი ლოგიკიდან

A ამბობს: "B იტყუება."
B ამბობს: "C იტყუება."
C ამბობს: "A და B იტყუებიან."
მაშ, ვინ იტყუება მათგან?
ამ შეკითხვზე პასუხის გასაცემად ჩვენ ვაკოდირებთ "ჭეშმარიტს" როგორც 1 და "ტყუილს" როგორც 0 რგოლში ZZ/(2):

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

ერთადერთი ამონახსნია ის, რომ A და C იტყუებოდნენ, და B ამბობდა მართალს.

გეოგრაფიული რუკების გაფერადება

შესაძლებელია თუ არა გავაფერადოთ ქვეყნები რუკაზე სამ ფერად ისე, რომ არცერთ ორ მეზობელს არ ჰქონდეს ერთი და იგივე ფერი?

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

ინტერპრეტაცია არის ის, რომ ასეთ შემთხვევაში მართლაც არსებობს შესაბამის გაფერადება. კერძოდ, თუ 0 ნიშნავს ლურჯს, 1 ნიშნავს წითელს, და -1 ნიშნავს მწვანეს, ვღებულობთ [ქვეყანა 1 = წითელი; ქვეყანა 2 = ლურჯი; ქვეყანა 3 = მწვანე; ქვეყანა 4 = წითელი; ქვეყანა 5 = მწვანე; ქვეყანა 6 = ლურჯი]

ჰერონის ფორმულა

შესაძლებელია, რომ სამკუთხედის ფართობი გამოვსახოთ , როგორც მისი გვერდების სიგრძეების ფუნქცია?

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

ინტერპრეტაცია არის ის, რომ ჩვენ გვაქვს s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). ეს ნიშნავს, რომ იმ სამკუთხედის ფართობის თავის თავზე ნარავლი რომლის გვერდები არიან a, b, c არის p(p-a)(p-b)(p-c) სადაც p = 1/2(a+b+c) არის ნახევარპერიმეტრი. მაშასადემე პასუხია "კი".