CoCoA는 무엇입니까?

CoCoA 프로그램은 숫자와 다항식 계산을 위한 프로그램입니다.
이 프로그램은 누구나 무료로 사용할 수 있습니다.
이 프로그램은 다양한 운영체제 위에서 사용될 수 있습니다.
이 프로그램은 전문 연구자들에 의해 사용되고 있습니다. 그러나 단순한 계산을 위해서도 사용될 수 있습니다.

매우 큰 정수들의 계산

일반적으로 32-bit 컴퓨터에서 다룰 수 있는 가장 큰 정수는 2^32-1 입니다. 그러나 CoCoA는 강력한 GMP 라이브러리를 사용하여 심지어 2^300000 의 정수값을 계산할 수 있습니다. 시도해 보세요!

2^32-1;

4294967295

2^64-1;

18446744073709551615

유리수의 계산

CoCoA는 매우 정확한 나눗셈 계산이 가능합니다: 결코 근사값을 주지 않습니다! 예를 들면 CoCoA는 1/3과 0.3333333333333을 전혀 다른 값으로 인식합니다.

(1/3) * 3;

0.3333333333333 * 3;

9999999999999/10000000000000

다항식들의 계산

CoCoA는 다항식 계산을 위해 특별히 제작된 프로그램입니다. 이 프로그램을 통해 다항식의 전개, 곱하기, 나누기 그리고 인수분해등을 할 수 있습니다.

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

선형 연립방정식의 풀이

CoCoA 는 선형 연립 방정식의 해를 구하는데 사용될 수 있습니다. 풀고자 하는 식 f = c을 다항식 f - c 으로 써 주기만 하면 됩니다. 물론 CoCoA는 다항식들의 연립방정식 풀이를 위해 사용될 수 있습니다. 하지만 이것은 더 어렵기 때문에 나중에 보이도록 하겠습니다. 이제 다음과 같이 주어진 선형 연립 방정식을 풀어보면,

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

따라서 주어진 선형 연립방정식의 해는 (z=21/5, x=-3/5, y=8/5) 입니다.

음이 아닌 정수해의 계산

다음과 같이 주어진 연립 방정식의 음이 아닌 정수해를 구할 수 있습니까?

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

위의 값은 단지 4개의 해만 존재한다는 것을 말해줍니다. (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

논리값 계산

A 가 말했습니다: "B 는 거짓말을 한다"
B 가 말합니다: "C 가 거짓말을 한다."
C 또한 말합니다: "A 와 B 는 거짓말을 하고있다."
자, 그럼 여기서 누가 거짓말을 하고 있습니까?
이 질문에 답을 주기 위해 '참'과 '거짓'에 각각, ZZ/(2)의 원소인, 1과 0의 값을 대응시키면 다음과 같이 답을 구할 수 있습니다.

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

위의 결과로부터 이 질문에 대한 유일한 답이 다음과 같다는 것을 알게 됩니다.
"A 와 C 는 거짓말을 하고, B는 진실을 이야기한다"

지도 색칠하기

다음과 같이 주어진 지도에 대해, 서로 인접한 두 나라는 다른 색이 되도록 세가지의 색을 사용하여 색칠하는 것이 가능할까요?

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

위의 결과로부터 3가지 색을 가지고 서로 인접한 나라는 다른 색이 되도록 색칠하는 것이 가능하다는 것을 알 수 있습니다. 만일 0이 파란색을, 1이 붉은색을, -1이 초록색을 의미한다면 [나라 1 = 붉은색; 나라 2 = 파란색; 나라 3 = 초록색; 나라 4 = 붉은색; 나라 5 = 초록색; 나라 6 = 파란색]은 그러한 색칠하기의 한가지 예가 됩니다.

Heron의 공식

삼각형의 면적을 세변의 길이에 대한 함수로 표현하는 것이 가능할까요?

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

위의 결과로부터 삼각형의 세변의 길이를 a, b, c 으로 놓으면 다음의 결과를 얻습니다. s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). 따라서 p = 1/2(a+b+c)으로 놓으면, 삼각형 면적의 제곱은 p(p-a)(p-b)(p-c)으로 주어진다는 것을 알 수 있습니다..