Čo je CoCoA?

Veľmi veľké čísla

Najväčšie celé číslo, ktoré je možné reprezentovať na 32-bitovom počítači, je 2^32-1. CoCoA môže vďaka výkonnej GMP knižnici počítať s tak veľkými číslami ako 2^300000: vyskúšaj si to!

2^32-1;

4294967295

2^64-1;

18446744073709551615

Racionálne čísla

CoCoA pracuje so zlomkami presne - nikdy nezaokrúhľuje! Čiže 1/3 sa v žiadnom prípade nerovná 0.3333333333333 .

(1/3) * 3;

0.3333333333333 * 3;

9999999999999/10000000000000

Polynómy

CoCoA sa zameriava najmä na výpočty s polynómami: násobí, delí, faktorizuje, ...

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

Lineárne systémy

CoCoA vie riešiť sústavy lineárnych rovníc. Stačí napísať každú rovnicu

f
= c

ako polynóm f - c. CoCoA dokáže riešiť aj sústavy polynómov, je to však trochu zložitejšie, ako neskôr uvidíme. Teraz vyriešme

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

Čiže riešenie je (z=21/5, x=-3/5, y=8/5)

Nezáporné celočíselné riešenia

Vieš nájsť trojice nezáporných celých čísel vyhovujúcich tejto sústave?

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

To znamená, že sústava má len štyri riešenia: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

Príklad z logiky

A hovorí: "B klame."
B hovorí: "C klame."
C hovorí: "A a B klamú"
Takže kto tu vlastne klame?
Ak chceme nájsť odpoveď, zakódujeme PRAVDA ako 1 a NEPRAVDA ako 0 v ZZ/(2):

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

Jediné riešenie je, že A a C klamali, a B hovoril pravdu.

Farbenie zemepisnej mapy

Je možné zafarbiť krajiny na mape troma farbami tak, aby žiadne dve susedné krajiny nemali rovnakú farbu?

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

To znamená, že v tomto prípade takéto zafarbenie naozaj existuje. Napíklad ak 0 znamená modrú, 1 červenú a -1 zelenú, dostaneme [krajina 1 = červená; krajina 2 = modrá; krajina 3 = zelená; krajina 4 = červená; krajina 5 = zelená; krajina 6 = modrá]

Herónov vzorec

Je možné vyjadriť obsah trojuholníka ako funkciu dĺžok jeho strán?

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

To znamená, že s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). Teda štvorec obsahu trojuholníka so stranami a, b, c je p(p-a)(p-b)(p-c), kde p = 1/2(a+b+c) je polovica obvodu. Odpoveď je preto ÁNO.