CoCoAって何？

• CoCoA は「数」や「多項式」を計算するための数式処理ソフトです。
• 無料です。
• いろいろな OS 上で動作します。
• 多くの研究者によって使われています。簡単な計算にも有効なことから研究者のみならず有効に使うことができます。

CoCoA で何が計算できるか？

多倍長整数 有理数 多項式 線形システム

非負整数解 論理計算の例 地図の色分け ヘロンの公式

多倍長整数

32bit マシンの最大 "マシン整数 (machine integer)" は 2^32-1 ですが, CoCoAでは, 2^300000 ほどの大きさの数さえ計算できます。（パワフル GMP ライブラリに感謝。）試しにどうぞ！

2^32-1; 

4294967295

2^64-1; 

18446744073709551615

有理数

CoCoA は正確な分数表現を持ちます。CoCoA は分数を決して近似しません！だから，1/3 と 0.3333333333333 は異なるものです。

(1/3) * 3;

1

0.3333333333333 * 3;

9999999999999/10000000000000

多項式

多項式計算において CoCoA は特化しています。乗法，割り算，因数分解等々の計算をすることができます。

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

線形システム

CoCoA は線形システムを解くことができます。そのとき，入力としてすべの方程式 f = c　を f - c として入力する必要があります。CoCoA は多項式システム（非線形システム）も解くことも可能ですが，少し難しいのでそれは後で見ることでしょう。今は次の線形システムを解きます。

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

したがって，この解は (z=21/5, x=-3/5, y=8/5) です。

非負整数解

次の連立方程式の負でない整数解の組を求めることができますか？

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

この解釈は，4 組の解 (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0) だけが負でない整数解として存在するということです。

論理計算の例

A のコメント： "B は嘘つきだ。"
B のコメント： "C は嘘つきだ。"
C のコメント： "A と B は嘘つきだ。"
さて，ここで誰が嘘を言っているでしょう？
この問題を解くため， ZZ/(2) 上で 真 (TRUE) を 1 とし 偽 (FALSE) を 0 として CoCoA で以下のように計算します。

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

以上の結果より，A と C　が嘘つきで，B が本当のことを言っていることがわかります。

地図の色分け

接している 2 国は同じ色を使わないという条件で，次の地図上の国々を 3 色で色分けできますか？

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

この解釈は，色分けは可能です。例えば，0 を青，1 を赤，－1 を緑とすると，以下の図のように ［ 国１＝赤； 国２＝青； 国３＝緑； 国４＝赤； 国５＝緑； 国６＝青 ］という答えを得ることができます。

ヘロンの公式

三角形の 3 辺の長さの関数として，三角形の面積を表すことは可能ですか？

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

この解釈は，まず次の式が成立します。 s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c) この式の意味は，a, b, c, という 3 辺を持つ三角形の面積の 2 乗は p = 1/2(a+b+c) としたとき，p(p-a)(p-b)(p-c) と等しくなるということです。したがって答えは "YES" 可能です。