Home Page
|
CoCoA System
Computations in
Commutative
Algebra
什麽是CoCoA?
|
|
This pages counts
visits
by
visitors
- CoCoA是用于数字运算与多项式运算的软件。
- 它是无偿提供使用的。
- 它适用于很多操作系统。
- 它不仅广泛用于专业研究,而且也可用来做“简单”运算。
大数运算
在一个32字节的计算机上我们可以使用的最大整数是 2^32-1,
但是在CoCoa中,
借助强大GMP的储存功能我们可以计算大到 2^300000 的整数:来试一下!
2^32-1;
4294967295
2^64-1;
18446744073709551615
分数
CoCoA在分数计算中非常精确:它从来不约去数字!因此在CoCoa中 1/3
和 0.3333333333333 是不同的两个数。
(1/3) * 3;
1
0.3333333333333 * 3;
9999999999999/10000000000000
多项式运算
CoCoA着重于多项式运算:它可用于多项式的乘,除,因式分解, ...
(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);
x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2
Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);
record[
RemainingFactor := 1,
factors := [x^2 -2*z^2, x -y],
multiplicities := [1, 2]]
]
线性方程组
CoCoA 可用来解线性方程组.你只需将每个方程
f = c
写成多项式
f - c
的形式即可.CoCoA 也可用来解多项式方程组,
但这其中的道理比较复杂,我们以后再谈。现在我们来解下列线性方程组
System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);
[x +3/5, y -8/5, z -21/5]
因此方程组的解是(z=21/5, x=-3/5,
y=8/5)
非负整数解问题
你能找到下列方程组的所有非负整数解吗?
3x - 4y + 7z | =2 |
2x - 2y + 5z | =10 |
M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;
[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]
结果告诉我们此方程组只有4组非负整数解,
(0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).
逻辑运算
A 说: "B 在说谎."
B 说: "C 在说谎."
C 说: "A 和 B 都在说谎."
现在究竟是谁在说谎呢?
为回答这个问题,在ZZ/(2)中
我们用1来表示真,用0来表示假。
use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);
[b +1, a, c]
我们得到的唯一解答是 A 和 C 在说谎,B 说的是事实.
地图添色问题
你能用3种颜色填充下面地图并且使得相邻两国没有相同颜色吗?
use P ::= ZZ/(3)[x[1..6]];
define F(X) return X*(X-1)*(X+1); enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3], [2,3],[2,4],[2,5], [3,4],[3,6],
[4,5],[4,6], [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
| edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);
[x[2], x[1] -1, x[3] +1, x[4] -1, x[6], x[5] +1]
根据上面结果答案是肯定的。
如果0代表蓝色, 1代表红色, -1代表绿色, 我们得到
[国家 1 = 红色; 国家 2 = 蓝色; 国家 3 = 绿色;
国家 4 = 红色; 国家 5 = 绿色; 国家 6 = 蓝色]
Heron 公式
一个三角形的面积可以用它的三边给出吗?
use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0, y];
Hp := ideal(a^2 - (x[2]^2+y^2), b^2 - (x[1]^2+y^2),
c - (x[2]-x[1]), 2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;
a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2
factor(f - 16*s^2);
record[
RemainingFactor := 1,
factors := [a +b -c, a -b +c, a +b +c, a -b -c],
multiplicities := [1, 1, 1, 1]
]
结果告诉我们下列公式
s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c).
也即,如果一个三角形的三边分别是 a,b 和 c,那麽此三角形的面积是
p(p-a)(p-b)(p-c),这里 p = 1/2(a+b+c) 代表周长的一半.因此我们得到肯定的答案。
Written by Ping Li
Please send comments or suggestions to cocoa(at)dima.unige.it
Last Update: 20 November 2018