Шта је CoCoA?

CoCoA је програм за рачунање са бројевима и полиномима.
Бесплатан је.
Ради на многим оперативним системима.
Користи га пуно истраживача, али може да буде од користи и за «једноставна» рачунања.

Веома велики цели бројеви

Највећи цео број који машина може да одреди на 32-битном компјутеру је 2^32-1, али CoCoA, захваљујући моћној GMP библиотеци, може чак да израчуна бројеве велике као 2^300000: пробајте сами!

2^32-1;

4294967295

2^64-1;

18446744073709551615

Рационални бројеви

CoCoA је веома прецизан са разломцима: никада их не апроксимира! Тако је 1/3 различита од 0.3333333333333

(1/3) * 3;

0.3333333333333 * 3;

9999999999999/10000000000000

Полиноми

CoCoA је специјализован за рачун са полиномима: може да их множи, дели, раставља на чиниоце...

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

Системи линеарних једначина

CoCoA може да реши систем линеарних једначина. Једино што је потребно је да напишете сваку једначину f = c као полином

f -
 c

. CoCoA такође може да решава системе нелинеарних јендачина, али је то мало теже као што ћемо видети касније. Сада можемо да решимо

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

Дакле, решење је: (z=21/5, x=-3/5, y=8/5).

Ненегативна цела решења

Да ли можете пронаћи уређене тројке ненегативних целих решења следећег система?

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

Овај резултат интерпретирамо тако што кажемо да има само четири решења:
(0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

Пример из математичке логике

А каже: «Б лаже.»
Б каже: «Ц лаже.»
Ц каже: «А и Б лажу.»
Ко заправо лаже?
За одговор на ово питање кодираћемо ТАЧНО са 1, а НЕТАЧНО са 0 у групи ZZ/(2):

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

Јединствено решење је да су А и Ц лагали, а Б је говорио истину.

Бојење географске карте

Да ли је могуће на географској карти обојити државе са три различите боје, али тако да две суседне немају исту боју?

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

Овај одговор интерпретирамо тако што кажемо да је могуће обојити карту у овом случају. На пример, ако 0 означава плаво, 1 црвено, а -1 зелено, добијемо [земља 1 = црвено; земља 2 = плаво; земља 3 = зелено; земља 4 = црвено; земља 6 = плаво].

Херонова формула

Да ли је могуће изразити површину троугла као функцију дужине његових страна?

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

Дакле, формула је s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). Значи, квадрат површине троугла са страницама дужине a, b, c je p(p-a)(p-b)(p-c), где је p = 1/2(a+b+c) полуобим. Значи, одговор је ДА.