Τι είναι το CoCoA;

• Το CoCoA είναι ένα πρόγραμμα για υπολογισμούς με αριθμούς και πολυώνυμα.
• Είναι ελεύθερο.
• Δουλεύει σε πολλά διαφορετικά λειτουργικά συστήματα.
• Χρησιμοποιείται από πολλούς ερευνητές, αλλά είναι χρήσιμο ακόμα και για "απλούς" υπολογισμούς.

Τι μπορεί να υπολογιστεί στο CoCoA ;

Πολύ Μεγάλοι Ακέραιοι Ρητοί Αριθμοί Πολυώνυμα Γραμμικά Συστήματα

Μη αρνητικές Ακέραιες Λύσεις Παράδειγμα Λογικής Χρωματισμός Γεωγραφικού Χάρτη Ο τύπος του Ήρωνα

Πολύ Μεγάλοι Ακέραιοι

Ο μεγαλύτερος "αριθμός μηχανής" που μπορείτε να χρησιμοποιήσετε σε έναν 32-bit υπολογιστή είναι 2^32-1, αλλά το CoCoA, χάρη στην ισχυρή βιβλιοθήκη GMP, μπορεί να υπολογίσει ακόμα και το 2^300000: δοκιμάστε το!

2^32-1; 

4294967295

2^64-1; 

18446744073709551615

Ρητοί Αριθμοί

Το CoCoA είναι πολύ ακριβές με κλάσματα: δεν κάνει ποτέ προσεγγίσεις! Έτσι το 1/3 είναι αρκετά διαφορετικό από το 0.3333333333333

(1/3) * 3;

1

0.3333333333333 * 3;

9999999999999/10000000000000

Πολυώνυμα

Το CoCoA είναι εξειδικευμένο σε υπολογισμούς με πολυώνυμα: πολλαπλασιάζει, διαιρεί, παραγοντοποιεί, ...

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

Γραμμικά Συστήματα

Το CoCoA μπορεί να λύσει γραμμικά συστήματα. Απλώς πρέπει να γράψετε κάθε εξίσωση f = c σαν το πολυώνυμο f - c. Το CoCoA μπορεί επίσης να λύσει συστήματα πολυωνύμων, αλλά αυτό είναι λίγο δυσκολότερο και θα το δούμε αργότερα. Τώρα λύνουμε:

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

Άρα η λύση είναι (z=21/5, x=-3/5, y=8/5)

Μη αρνητικές Ακέραιες Λύσεις

Μπορείτε να βρείτε όλες τις τριάδες μη-αρνητικών ακέραιων λύσεων του παρακάτω συστήματος;

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

Η ερμηνεία είναι ότι υπάρχουν μόνο τέσσερις λύσεις: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

Παράδειγμα Λογικής

Ο Α λέει: "Ο B λέει ψέματα."
Ο B λέει: "Ο C λέει ψέματα."
Ο C λέει: "Ο A και ο B λένε ψέματα."
Ποιος λέει ψέματα τελικά εδώ;
Για να απαντήσουμε σε αυτήν την ερώτηση κωδικοποιούμε το ΑΛΗΘΕΣ με 1 και το ΨΕΥΔΕΣ με 0 στο σώμα ZZ/(2):

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

Η μοναδική λύση είναι ότι οι A και C έλεγαν ψέματα, και ο B έλεγε αλήθεια.

Χρωματισμός Γεωγραφικού Χάρτη

Μπορούν οι χώρες σε ένα χάρτη να χρωματιστούν με τρία χρώματα, έτσι ώστε δυο γειτονικές χώρες να μην έχουν ποτέ το ίδιο χρώμα;

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

Η ερμηνεία είναι ότι υπάρχει πράγματι ένας χρωματισμός σε αυτήν την περίπτωση. Για παράδειγμα, αν 0 σημαίνει μπλέ, 1 σημαίνει κόκκινο, και -1 σημαίνει πράσινο, παίρνουμε [χώρα 1 = κόκκινο, χώρα 2 = μπλέ, χώρα 3 = πράσινο, χώρα 4 = κόκκινο, χώρα 5 = πράσινο, χώρα 6 = μπλέ]

Ο τύπος του Ήρωνα

Μπορεί το εμβαδό ενός τριγώνου να εκφραστεί σα συνάρτηση του μήκους των πλευρών του;

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

Η ερμηνεία είναι ότι ισχύει s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). Αυτό σημαίνει ότι το τετράγωνο του εμβαδού του τριγώνου με πλευρές a, b, c είναι p(p-a)(p-b)(p-c) όπου p = 1/2(a+b+c) η ημιπερίμετρος. Άρα η απάντηση είναι ΝΑΙ.