Co je CoCoA?

Velmi velká čísla

Nejvetsí strojové celé císlo, které 32-bitový počítač může vypočítat je 2^32 - 1, ale CoCoA využívá mocnou vypočítávánou knihovnu neohraničené přesnosti GMP, a tak může vypočítat také 2^300000: zkuste to!

2^32-1;

4294967295

2^64-1;

18446744073709551615

Racionální čísla

CoCoA je velmi přesný při práci se zlomky: Nikdy je nekrátí na desetinná čísla! Tedy 1/3 je něco jiného než 0,3333333333333.

(1/3) * 3;

0.3333333333333 * 3;

9999999999999/10000000000000

Polynomy

CoCoA je odborníkem na polynomy: může je násobit, dělit, faktorovat, ....

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

Soustavy lineárních rovnic

CoCoA dokáže řešit soustavy lineárních rovnic. Stačí kodifikovat každou rovnici typu f = c z polynomu

f
- c

. Také umí řešit soustavy nelineárních rovnic, i když to je trochu těžší (budeme o tom mluvit později).

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

Tak řešení je (z=21/5, x=-3/5, y=8/5).

Nezáporná řešení

Dokážete nalézt trojici nezáporných čísel, která vyhovuje dané soustavě?

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

Tak máme jenom čtyři řešení: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

Kdo lže?

A říká: "B lže."
B říká: "C lže."
C říká: "A a B lžou."
Tak, kdo lže?
Pro zjištění odpovědi na tuhle otázku zakódujeme PRAVDA jako 1 a NEPRAVDA jako 0 v ZZ/(2)

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

Jedinou možností je : A a C lžou, pokud B má pravdu.

Obarvíme zeměpisnou mapu

Můžeme obarvit státy na mapě s využitím pouhých tří barev tak, že každé dvě sousedící země mají odlišnou barvu?

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

Řešení lze formalizovat takto: proměnné x[1], x[2],... .., x[6] jsou státy, zatímco čísla -1, 0, 1 identifikují barvy, na příklad -1 znamená "zelená", 0 "modrá", a 1 je "červená". CoCoA najde možné zbarvení: Stát 1 = červený, stát 2 = modrý ... Stát 5 = zelený. Dostaneme:

Heronův vzorec

Můžeme vypočítat obsah trojúhelníka podle délky jeho stran?

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

To znamená, že s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). Čtverec obsahu trojúhelníka se stranami a,b,c je p(p-a)(p-b)(p-c), kde p = 1/2(a+b+c) je polovina obvodu trojúhelníka. To je Heronův vzorec!