O que é CoCoA?

Inteiros muito grandes

O maior "inteiro máquina" que um computador de 32 bits pode calcular é 2^32-1, porém CoCoA, utilizando a poderosa biblioteca de cálculo a precisão arbitrária GMP, pode calcular números tão grandes quanto 2^300000: experimentem!

2^32-1;

4294967295

2^64-1;

18446744073709551615

Números Racionais

CoCoA é muito preciso com as frações : nunca as aproxima! Assim 1/3 é diferente de 0.3333333333333

(1/3) * 3;

0.3333333333333 * 3;

9999999999999/10000000000000

Polinômios

CoCoA é especializado em polinômios: pode multiplica-los, dividi-los, fatora-los, ....

(x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);

x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2

Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);

record[
  RemainingFactor := 1,
  factors := [x^2 -2*z^2,  x -y],
  multiplicities := [1,  2]]
]

Sistemas de equações lineares

CoCoA pode resolver sistemas de equações lineares, é suficiente escrever cada equação do tipo f = c na forma

f -
c

. Pode resolver também sistemas de equações não lineares, porém é um pouco mais difícil e falaremos depois. Resolveremos agora :

x-y+z	=2
3x-z	=-6
x+y	=1

System := ideal(x-y+z-2, 3*x-z+6, x+y-1);
ReducedGBasis(System);

[x +3/5,  y -8/5,  z -21/5]

Assim a solução é (z=21/5, x=-3/5, y=8/5).

Soluções inteiras não negativas

É possível encontrar ternas de inteiros não negativos soluções do seguinte sistema?

3x - 4y + 7z	=2
2x - 2y + 5z	=10

M := mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
H := HilbertBasisKer(M);
L := [h In H | h[4] <= 1];
L;

[[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]

A interpretação é que existem justamente quatro soluções: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

Quem está mentindo?

A diz: "B mente."
B diz: "C mente."
C diz: "A e B mentem."
Então, quem está mentindo?
Para responder esta pergunta codificamos VERDADEIRO com 1 e FALSO com 0 em ZZ/(2):

use ZZ/(2)[a,b,c];
I1 := ideal(a, b-1);
I2 := ideal(a-1, b);
A := intersect(I1, I2);
I3 := ideal(b, c-1);
I4 := ideal(b-1, c);
B := intersect(I3, I4);
I5 := ideal(a, b, c-1);
I6 := ideal(b-1, a, c);
I7 := ideal(b, a-1, c);
I8 := ideal(b-1, a-1, c);
C := IntersectList([I5, I6, I7, I8]);
ReducedGBasis(A + B + C);

[b +1,  a,  c]

A única solução é que A e C mentem, e que B diz a verdade.

Pintando um mapa geografico

É possível pintar as regiões de um mapa usando somente três cores de modo que duas regiões vizinhas não partilhem a mesma cor?

use P ::= ZZ/(3)[x[1..6]];
define F(X)  return X*(X-1)*(X+1);  enddefine;
VerticesEq := [ F(x[i]) | i in 1..6 ];
edges := [[1,2],[1,3],  [2,3],[2,4],[2,5],  [3,4],[3,6],
          [4,5],[4,6],  [5,6]];
EdgesEq := [ (F(x[edge[1]])-F(x[edge[2]]))/(x[edge[1]]-x[edge[2]])
                  |  edge in edges ];
I := ideal(VerticesEq) + ideal(EdgesEq) + ideal(x[1]-1, x[2]);
ReducedGBasis(I);

[x[2],  x[1] -1,  x[3] +1,  x[4] -1,  x[6],  x[5] +1]

O resultado se interpreta do seguinte modo : as variáveis x[1], x[2],..., x[6] representam as regiões e os números -1, 0, 1 identificam as cores. CoCoA encontra uma coloração possível: cor 0 para a região 2, cor 1 para a região 1,..., cor -1 para a região 5. Por exemplo, se associamos a 0 a cor azul, a 1 a cor vermelha e a -1 a cor verde, obtemos:

Fórmula de Heron

É possível exprimir a área de um triângulo em função do comprimento dos seus lados?

use QQ[x[1..2],y,a,b,c,s];
A := [x[1], 0];
B := [x[2], 0];
C := [ 0,   y];
Hp := ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
            c   - (x[2]-x[1]),   2*s - c*y);
E := elim(x[1]..y, Hp);
f := monic(gens(E)[1]);
f;

a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2

factor(f - 16*s^2);

record[
  RemainingFactor := 1,
  factors := [a +b -c,  a -b +c,  a +b +c,  a -b -c],
  multiplicities := [1,  1,  1,  1]
]

O resultado se traduz na relação: s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c). Isto significa que o quadrado da área de um triângulo de lados a,b,c é p(p-a)(p-b)(p-c) onde p = 1/2(a+b+c) representa o semi-perímetro. Esta é a fórmula de Heron! Então a área de um triângulo pode ser expressa em função do comprimento dos seus lados.