CoCoA System
Computations in Commutative Algebra

Kaj je CoCoA?

This pages counts visits by visitors



Ka j lahko delamo s CoCoA?

  • Zelo velika cela števila
  • Racionalna števila
  • Polinomi
  • Sistemi linearnih enačb
  •  
  • Nenegativne celoštevilske rešitve
  • Logična naloga
  • Barvanje zemljevida
  • Heronov obrazec

  • Zelo velika cela števila

    Na jvečje "stro jno število", ki ga imamo na 32-bitnem računalniku, je 2^32 −1. S programom CoCoA pa lahko zaradi obsežne GMP knjižnice računamo celo s števili, velikimi kot 2300000 . Poskusite!
    2^32-1; 
    4294967295
    2^64-1; 
    18446744073709551615

    Racionalna števila

    CoCoA je zelo natančen pri ulomkih - nikoli ne dela približkov! Tako je 1/3 povsem neka j drugega kot 0.3333333333333.
    (1/3) * 3;
    1
    0.3333333333333 * 3;
    9999999999999/10000000000000

    Polinomi

    Polinomi CoCoA je narejen posebej za računanje s polinomi: zna jih deliti, množiti, faktorizirati, ...
    (x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);
    x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2
    Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);
    Record[
      Exponents := [1, 2],
      Factors := [x^2 -2*z^2, x -y],
      RemainingFactor := 1
    ]

    Sistemi linearnih enačb

    S CoCoA lahko rešujemo sisteme linearnih enačb. Vse, kar moramo storiti, je, da vsako enačbo oblike f = c zapišemo kot polinom f − c. S CoCoA lahko rešujemo tudi sisteme nelinearnih polinomskih enačb, vendar je to nekoliko težje, zato si bomo to ogledali kasneje. Rešimo:
    x-y+z=2
    3x-z=-6
    x+y=1
    System := Ideal(x-y+z-2, 3*x-z+6, x+y-1);
    ReducedGBasis(System);
    [z - 21/5, x + 3/5, y - 8/5]
    Rešitev sistema je (z = 21/5, x = −3/5, y = 8/5).

    Nenegativne celoštevilske rešitve

    Ali znate poiskati tro jice nenegativnih celih števil, ki rešijo naslednji sistem?
    3x - 4y + 7z=2
    2x - 2y + 5z=10
    M := Mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
    H := HilbertBasis(M);
    L := [A In H | A[4] <= 1];
    L;
    [[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]
    To pomeni, da obstaja jo samo štiri rešitve: (0, 10, 6), (6, 11, 4), (12, 12, 2) in (18, 13, 0).

    Logična naloga

    A reče: "B laže."
    B reče: "C laže."
    C reče: "A in B lažeta."
    Kdo laže in kdo ne?
    Da bi odgovorili na to vprašanje v obsegu ZZ/(2) zakodiramo PRAVILNO z 1 in NAPA ČNO z 0:
    Use ZZ/(2)[a,b,c];
    I1 := Ideal(a, b-1);
    I2 := Ideal(a-1, b);
    A := Intersection(I1, I2);
    I3 := Ideal(b, c-1);
    I4 := Ideal(b-1, c);
    B := Intersection(I3, I4);
    I5 := Ideal(a, b, c-1);
    I6 := Ideal(b-1, a, c);
    I7 := Ideal(b, a-1, c);
    I8 := Ideal(b-1, a-1, c);
    C := Intersection(I5, I6, I7, I8);
    ReducedGBasis(A + B + C);
    [a, b+1, c]
    Edina rešitev je ta, da A in C lažeta, B pa govori resnico.

    Barvanje zemljevida

    Ali lahko s tremi barvami pobarvamo države na zemljevidu tako, da nobeni dve sosednji državi ne bosta iste barve?

    Use P ::= ZZ/(3)[x[1..6]];
    Define F(X)  Return X*(X-1)*(X+1);  EndDefine;
    VerticesEq := [ F(x[I]) | I In 1..6 ];
    Edges := [[1,2],[1,3],[2,3], [2,4], [2,5], [3,4], [3,6],
                [4,5], [4,6], [5,6]];
    EdgesEq := [ (F(x[A[1]])-F(x[A[2]]))/(x[A[1]]-x[A[2]])
                      |  A In Edges ];
    I := Ideal(VerticesEq) + Ideal(EdgesEq) + Ideal(x[1]-1, x[2]);
    ReducedGBasis(I);
    [x[2], x[1] - 1, x[3] + 1, x[4] - 1, x[6], x[5] + 1]
    Rezultat nam pove, da je v tem primeru res mogoče pobarvati zemljevid s tremi bar- vami. Npr. če 0 pomeni modro, 1 rdečo in -1 zeleno, dobimo [država 1 = rdeča, država 2 = modra, država 3 = zelena, država 4 = rdeča, država 5 = zelena, država 6 = modra].


    Heronov obrazec

    Ali je mogoče izraziti ploščino trikotnika kot funkcijo dolžin njegovih stranic?

    Use QQ[x[1..2],y,a,b,c,s];
    A := [x[1], 0];
    B := [x[2], 0];
    C := [ 0,   y];
    Hp := Ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
                c   - (x[2]-x[1]),   2*s - c*y);
    E := Elim(x[1]..y,Hp);
    F := Monic(Comp(Gens(E),1));
    F;
    a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2
    Factor(F - 16*s^2);
    [[a + b + c, 1], [a + b - c, 1], [a - b + c, 1], [a - b - c, 1]]
    Rezultat razložimo takole: Vemo, da je
    s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c).
    To pomeni, da je kvadrat ploščine trikotnika s stranicami a, b in c enak p(p −a)(p−b)(p−c), kjer je p = 1/2(a + b + c) polovica obsega trikotnika.

    Written by Urška Rihtaršič
    Please send comments or suggestions to cocoa(at)dima.unige.it
    Last Update: 19 September 2011