CoCoA System
Computations in Commutative Algebra

Ce este CoCoA?

This pages counts visits by visitors



Ce se poate calcula cu CoCoA?

  • Numere întregi foarte mari
  • Numere raţionale
  • Polinoame
  • Sisteme liniare
  •  
  • Soluţii întregi ne-negative
  • Exemplu logic
  • Harta geografică în culori
  • Formula lui Heron

  • Numere întregi foarte mari

    Cel mai mare "întreg-maşină" care se foloseşte pe un computer de 32 biţi este 2^32-1, dar CoCoA poate calcula numere de mărimea 2^300000, graţie puterii bibliotecii GMP. Încercaţi!
    2^32-1; 
    4294967295
    2^64-1; 
    18446744073709551615

    Numere raţionale

    Programul CoCoA este foarte precis când se lucrează cu fracţii: el nu le aproximează niciodată! Astfel 1/3 este foarte diferit de 0.3333333333333 .
    (1/3) * 3;
    1
    0.3333333333333 * 3;
    9999999999999/10000000000000

    Polinoame

    Programul CoCoA este specializat în calcule cu polinoame: el poate multiplica, divide, factoriza,...
    (x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);
    x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2
    Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);
    Record[
      Exponents := [1, 2],
      Factors := [x^2 -2*z^2, x -y],
      RemainingFactor := 1
    ]

    Sisteme liniare

    Programul CoCoA poate rezolva sisteme liniare. Este suficient să scrieţi fiecare ecuaţie f = c ca polinomul f - c. Programul CoCoA poate rezolva de asemenea sisteme neliniare, dar aceasta este ceva mai dificil, după cum vom vedea mai tâziu. Acum sa rezolvăm sistemul
    x-y+z=2
    3x-z=-6
    x+y=1
    System := Ideal(x-y+z-2, 3*x-z+6, x+y-1);
    ReducedGBasis(System);
    [z - 21/5, x + 3/5, y - 8/5]
    Deci soluţia este (z=21/5, x=-3/5, y=8/5)

    Soluţii întregi ne-negative

    Determinaţi toate tripletele de soluţii de întregi ne-negative ale următorului sistem:
    3x - 4y + 7z=2
    2x - 2y + 5z=10
    M := Mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
    H := HilbertBasis(M);
    L := [A In H | A[4] <= 1];
    L;
    [[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]
    Deci există numai următoarele patru soluţii: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

    Exemplu logic

    A zice: "B minte."
    B zice: "C minte."
    C zice: "A şi B mint."
    Deci, cine este mincinosul?
    Ca să răspundem la această întrebare codificăm ADEVARAT cu 1 şi FALS cu 0 în ZZ/(2):
    Use ZZ/(2)[a,b,c];
    I1 := Ideal(a, b-1);
    I2 := Ideal(a-1, b);
    A := Intersection(I1, I2);
    I3 := Ideal(b, c-1);
    I4 := Ideal(b-1, c);
    B := Intersection(I3, I4);
    I5 := Ideal(a, b, c-1);
    I6 := Ideal(b-1, a, c);
    I7 := Ideal(b, a-1, c);
    I8 := Ideal(b-1, a-1, c);
    C := Intersection(I5, I6, I7, I8);
    ReducedGBasis(A + B + C);
    [a, b+1, c]
    Unica soluţie este că A şi C mint, iar B zice adevărul.

    Harta geografică în culori

    Pot ţările de pe următoarea hartă să fie colorate cu trei culori astfel încât nici-o pereche de ţări adiacente să aibă aceeaşi culoare?

    Use P ::= ZZ/(3)[x[1..6]];
    Define F(X)  Return X*(X-1)*(X+1);  EndDefine;
    VerticesEq := [ F(x[I]) | I In 1..6 ];
    Edges := [[1,2],[1,3],[2,3], [2,4], [2,5], [3,4], [3,6],
                [4,5], [4,6], [5,6]];
    EdgesEq := [ (F(x[A[1]])-F(x[A[2]]))/(x[A[1]]-x[A[2]])
                      |  A In Edges ];
    I := Ideal(VerticesEq) + Ideal(EdgesEq) + Ideal(x[1]-1, x[2]);
    ReducedGBasis(I);
    [x[2], x[1] - 1, x[3] + 1, x[4] - 1, x[6], x[5] + 1]
    Interpretarea rezultatului este că există o asemenea colorare în acest caz. De exemplu, dacă 0 înseamnă albastru, 1 înseamnă roşu şi -1 înseamnă verde, obţinem [ţara 1 = roşu; ţara 2 = albastru; ţara 3 = verde; ţara 4 = roşu; ţara 5 = verde; ţara 6 = albastru]


    Formula lui Heron

    Este posibil să exprimăm aria unui triunghi ca funcţie de lungimea laturilor?

    Use QQ[x[1..2],y,a,b,c,s];
    A := [x[1], 0];
    B := [x[2], 0];
    C := [ 0,   y];
    Hp := Ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
                c   - (x[2]-x[1]),   2*s - c*y);
    E := Elim(x[1]..y,Hp);
    F := Monic(Comp(Gens(E),1));
    F;
    a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2
    Factor(F - 16*s^2);
    [[a + b + c, 1], [a + b - c, 1], [a - b + c, 1], [a - b - c, 1]]
    Obţinem deci:
    s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c).
    Altfel spus, pătratul ariei unui triunghi de laturi a, b, c este p(p-a)(p-b)(p-c) unde p = 1/2(a+b+c) este semiperimetrul. Deci răspunsul este DA.

    Written by Lucian Bădescu
    Please send comments or suggestions to cocoa(at)dima.unige.it
    Last Update: 19 September 2011