CoCoA System
Computations in Commutative Algebra

Co to jest CoCoA?

This pages counts visits by visitors



Co CoCoA potrafi obliczyć ?

  • Bardzo duże liczby naturalne
  • Liczby wymierne
  • Wielomiany
  • Układy równań liniowych
  •  
  • Rozwiązania w liczbach naturalnych
  • Przykład z logiki
  • Kolorowanie mapy
  • Wzór Herona

  • Bardzo duże liczby naturalne

    Największą, łatwo dostępną (przy użyciu 32-bitowej reprezentacji) liczbą całkowitą jest 2^32-1. CoCoA, dzięki znakomitej bibliotece GMP, potrafi obliczyć nawet 2^300000 - spróbuj!
    2^32-1; 
    4294967295
    2^64-1; 
    18446744073709551615

    Liczby wymierne

    CoCoA wyjątkowo dokładnie oblicza ułamki - po prostu nigdy ich nie przybliża! Dlatego 1/3 to nie to samo, co 0.3333333333333.
    (1/3) * 3;
    1
    0.3333333333333 * 3;
    9999999999999/10000000000000

    Wielomiany

    Specjalnością programu CoCoA są obliczenia wielomianowe: mnożenie, dzielenie, rozkład...
    (x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);
    x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2
    Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);
    Record[
      Exponents := [1, 2],
      Factors := [x^2 -2*z^2, x -y],
      RemainingFactor := 1
    ]

    Układy równań liniowych

    CoCoA potrafi rozwiązać układ równań liniowych. Trzeba tylko zapisać każde równanie f = c jako wielomian f - c. CoCoA potrafi również rozwiązywać układy równań wielomianowych, ale jest to trochę trudniejsze (przykład pojawi się później). Teraz spróbujemy rozwiązać układ
    x-y+z=2
    3x-z=-6
    x+y=1
    System := Ideal(x-y+z-2, 3*x-z+6, x+y-1);
    ReducedGBasis(System);
    [z - 21/5, x + 3/5, y - 8/5]
    Rozwiązaniem jest (z=21/5, x=-3/5, y=8/5)

    Rozwiązania w liczbach naturalnych

    Czy potrafisz znaleźć liczby naturalne, które spełniają poniższy układ równań?
    3x - 4y + 7z=2
    2x - 2y + 5z=10
    M := Mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
    H := HilbertBasis(M);
    L := [A In H | A[4] <= 1];
    L;
    [[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]
    Możemy odczytać wynik - program znalazł cztery rozwiązania: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

    Przykład z logiki

    A mówi: "B kłamie."
    B mówi: "C kłamie."
    C mówi: "A oraz B kłamią."
    Kto skłamał?
    Aby to rozwikłać zapisujemy PRAWDĘ jako 1, a FAŁSZ jako 0 w pierścieniu ZZ/(2):
    Use ZZ/(2)[a,b,c];
    I1 := Ideal(a, b-1);
    I2 := Ideal(a-1, b);
    A := Intersection(I1, I2);
    I3 := Ideal(b, c-1);
    I4 := Ideal(b-1, c);
    B := Intersection(I3, I4);
    I5 := Ideal(a, b, c-1);
    I6 := Ideal(b-1, a, c);
    I7 := Ideal(b, a-1, c);
    I8 := Ideal(b-1, a-1, c);
    C := Intersection(I5, I6, I7, I8);
    ReducedGBasis(A + B + C);
    [a, b+1, c]
    Jedyne rozwiązanie to: A i C kłamią, B mówi prawdę.

    Kolorowanie mapy

    Czy można pokolorować mapę trzema kolorami tak, aby żadne dwa sąsiednie państwa nie były pokolorowane tak samo?

    Use P ::= ZZ/(3)[x[1..6]];
    Define F(X)  Return X*(X-1)*(X+1);  EndDefine;
    VerticesEq := [ F(x[I]) | I In 1..6 ];
    Edges := [[1,2],[1,3],[2,3], [2,4], [2,5], [3,4], [3,6],
                [4,5], [4,6], [5,6]];
    EdgesEq := [ (F(x[A[1]])-F(x[A[2]]))/(x[A[1]]-x[A[2]])
                      |  A In Edges ];
    I := Ideal(VerticesEq) + Ideal(EdgesEq) + Ideal(x[1]-1, x[2]);
    ReducedGBasis(I);
    [x[2], x[1] - 1, x[3] + 1, x[4] - 1, x[6], x[5] + 1]
    Odczytujemy rozwiązanie - w tym przypadku odpowiedź brzmi TAK. Na przykład, jeśli 0 to kolor niebieski, 1 - czerwony, a -1 to zielony, otrzymujemy rozwiązanie: [państwo 1 = czerwony; państwo 2 = niebieski; państwo 3 = zielony; państwo 4 = czerwony; państwo 5 = zielony; państwo 6 = niebieski]


    Wzór Herona

    Czy można wyrazić pole trójkąta jako funkcję długości jego boków?

    Use QQ[x[1..2],y,a,b,c,s];
    A := [x[1], 0];
    B := [x[2], 0];
    C := [ 0,   y];
    Hp := Ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
                c   - (x[2]-x[1]),   2*s - c*y);
    E := Elim(x[1]..y,Hp);
    F := Monic(Comp(Gens(E),1));
    F;
    a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2
    Factor(F - 16*s^2);
    [[a + b + c, 1], [a + b - c, 1], [a - b + c, 1], [a - b - c, 1]]
    Otrzymujemy rozwiązanie:
    s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c).
    Oznacza to, że kwadrat pola trójkąta o bokach a, b, c jest równy p(p-a)(p-b)(p-c), gdzie p = 1/2(a+b+c) jest połową obwodu. Stąd odpowiedź brzmi TAK.

    Written by Marcin Dumnicki
    Please send comments or suggestions to cocoa(at)dima.unige.it
    Last Update: 19 September 2011