CoCoA System
Computations in Commutative Algebra

CoCoAって何?

This pages counts visits by visitors



CoCoA で何が計算できるか?

  • 多倍長整数
  • 有理数
  • 多項式
  • 線形システム
  •  
  • 非負整数解
  • 論理計算の例
  • 地図の色分け
  • ヘロンの公式

  • 多倍長整数

    32bit マシンの最大 "マシン整数 (machine integer)" は 2^32-1 ですが, CoCoAでは, 2^300000 ほどの大きさの数さえ計算できます。(パワフル GMP ライブラリに感謝。)試しにどうぞ!
    2^32-1; 
    4294967295
    2^64-1; 
    18446744073709551615

    有理数

    CoCoA は正確な分数表現を持ちます。CoCoA は分数を決して近似しません!だから,1/3 と 0.3333333333333 は異なるものです。
    (1/3) * 3;
    1
    0.3333333333333 * 3;
    9999999999999/10000000000000

    多項式

    多項式計算において CoCoA は特化しています。乗法,割り算,因数分解等々の計算をすることができます。
    (x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);
    x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2
    Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);
    Record[
      Exponents := [1, 2],
      Factors := [x^2 -2*z^2, x -y],
      RemainingFactor := 1
    ]

    線形システム

    CoCoA は線形システムを解くことができます。そのとき,入力としてすべの方程式 f = c を f - c として入力する必要があります。CoCoA は多項式システム(非線形システム)も解くことも可能ですが,少し難しいのでそれは後で見ることでしょう。今は次の線形システムを解きます。
    x-y+z=2
    3x-z=-6
    x+y=1
    System := Ideal(x-y+z-2, 3*x-z+6, x+y-1);
    ReducedGBasis(System);
    [z - 21/5, x + 3/5, y - 8/5]
    したがって,この解は (z=21/5, x=-3/5, y=8/5) です。

    非負整数解

    次の連立方程式の負でない整数解の組を求めることができますか?
    3x - 4y + 7z=2
    2x - 2y + 5z=10
    M := Mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
    H := HilbertBasis(M);
    L := [A In H | A[4] <= 1];
    L;
    [[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]
    この解釈は,4 組の解 (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0) だけが負でない整数解として存在するということです。

    論理計算の例

    A のコメント: "B は嘘つきだ。"
    B のコメント: "C は嘘つきだ。"
    C のコメント: "A と B は嘘つきだ。"
    さて,ここで誰が嘘を言っているでしょう?
    この問題を解くため, ZZ/(2) 上で 真 (TRUE) を 1 とし 偽 (FALSE) を 0 として CoCoA で以下のように計算します。
    Use ZZ/(2)[a,b,c];
    I1 := Ideal(a, b-1);
    I2 := Ideal(a-1, b);
    A := Intersection(I1, I2);
    I3 := Ideal(b, c-1);
    I4 := Ideal(b-1, c);
    B := Intersection(I3, I4);
    I5 := Ideal(a, b, c-1);
    I6 := Ideal(b-1, a, c);
    I7 := Ideal(b, a-1, c);
    I8 := Ideal(b-1, a-1, c);
    C := Intersection(I5, I6, I7, I8);
    ReducedGBasis(A + B + C);
    [a, b+1, c]
    以上の結果より,A と C が嘘つきで,B が本当のことを言っていることがわかります。

    地図の色分け

    接している 2 国は同じ色を使わないという条件で,次の地図上の国々を 3 色で色分けできますか?

    Use P ::= ZZ/(3)[x[1..6]];
    Define F(X)  Return X*(X-1)*(X+1);  EndDefine;
    VerticesEq := [ F(x[I]) | I In 1..6 ];
    Edges := [[1,2],[1,3],[2,3], [2,4], [2,5], [3,4], [3,6],
                [4,5], [4,6], [5,6]];
    EdgesEq := [ (F(x[A[1]])-F(x[A[2]]))/(x[A[1]]-x[A[2]])
                      |  A In Edges ];
    I := Ideal(VerticesEq) + Ideal(EdgesEq) + Ideal(x[1]-1, x[2]);
    ReducedGBasis(I);
    [x[2], x[1] - 1, x[3] + 1, x[4] - 1, x[6], x[5] + 1]
    この解釈は,色分けは可能です。例えば,0 を青,1 を赤,-1 を緑とすると,以下の図のように [ 国1=赤; 国2=青; 国3=緑; 国4=赤; 国5=緑; 国6=青 ]という答えを得ることができます。


    ヘロンの公式

    三角形の 3 辺の長さの関数として,三角形の面積を表すことは可能ですか?

    Use QQ[x[1..2],y,a,b,c,s];
    A := [x[1], 0];
    B := [x[2], 0];
    C := [ 0,   y];
    Hp := Ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
                c   - (x[2]-x[1]),   2*s - c*y);
    E := Elim(x[1]..y,Hp);
    F := Monic(Comp(Gens(E),1));
    F;
    a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2
    Factor(F - 16*s^2);
    [[a + b + c, 1], [a + b - c, 1], [a - b + c, 1], [a - b - c, 1]]
    この解釈は,まず次の式が成立します。
    s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c)
    この式の意味は,a, b, c, という 3 辺を持つ三角形の面積の 2 乗は p = 1/2(a+b+c) としたとき,p(p-a)(p-b)(p-c) と等しくなるということです。したがって答えは "YES" 可能です。

    Written by Katsusuke Nabeshima
    Please send comments or suggestions to cocoa(at)dima.unige.it
    Last Update: 19 September 2011