CoCoA System
Computations in Commutative Algebra

Co je CoCoA?

This pages counts visits by visitors



Co si můžete vypočítat s pomocí CoCoA?

  • Velmi velká čísla
  • Racionální čísla
  • Polynomy
  • Soustavy lineárních rovnic
  •  
  • Nezáporná řešení
  • Kdo lže?
  • Obarvíme zeměpisnou mapu
  • Heronův vzorec

  • Velmi velká čísla

    Nejvetsí strojové celé císlo, které 32-bitový počítač může vypočítat je 2^32 - 1, ale CoCoA využívá mocnou vypočítávánou knihovnu neohraničené přesnosti GMP, a tak může vypočítat také 2^300000: zkuste to!
    2^32-1; 
    4294967295
    2^64-1; 
    18446744073709551615

    Racionální čísla

    CoCoA je velmi přesný při práci se zlomky: Nikdy je nekrátí na desetinná čísla! Tedy 1/3 je něco jiného než 0,3333333333333.
    (1/3) * 3;
    1
    0.3333333333333 * 3;
    9999999999999/10000000000000

    Polynomy

    CoCoA je odborníkem na polynomy: může je násobit, dělit, faktorovat, ....
    (x-y)^2 * (x^4-4*z^4) / (x^2+2*z^2);
    x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2
    Factor(x^4 -2*x^3*y +x^2*y^2 -2*x^2*z^2 +4*x*y*z^2 -2*y^2*z^2);
    Record[
      Exponents := [1, 2],
      Factors := [x^2 -2*z^2, x -y],
      RemainingFactor := 1
    ]

    Soustavy lineárních rovnic

    CoCoA dokáže řešit soustavy lineárních rovnic. Stačí kodifikovat každou rovnici typu f = c z polynomu f - c. Také umí řešit soustavy nelineárních rovnic, i když to je trochu těžší (budeme o tom mluvit později).
    x-y+z=2
    3x-z=-6
    x+y=1
    System := Ideal(x-y+z-2, 3*x-z+6, x+y-1);
    ReducedGBasis(System);
    [z - 21/5, x + 3/5, y - 8/5]
    Tak řešení je (z=21/5, x=-3/5, y=8/5).

    Nezáporná řešení

    Dokážete nalézt trojici nezáporných čísel, která vyhovuje dané soustavě?
    3x - 4y + 7z=2
    2x - 2y + 5z=10
    M := Mat([[3, -4, 7, -2], [2, -2, 5, -10]]);
    H := HilbertBasis(M);
    L := [A In H | A[4] <= 1];
    L;
    [[0, 10, 6, 1], [6, 11, 4, 1], [12, 12, 2, 1], [18, 13, 0, 1]]
    Tak máme jenom čtyři řešení: (0, 10, 6), (6, 11, 4), (12, 12, 2), (18, 13, 0).

    Kdo lže?

    A říká: "B lže."
    B říká: "C lže."
    C říká: "A a B lžou."
    Tak, kdo lže?
    Pro zjištění odpovědi na tuhle otázku zakódujeme PRAVDA jako 1 a NEPRAVDA jako 0 v ZZ/(2)
    Use ZZ/(2)[a,b,c];
    I1 := Ideal(a, b-1);
    I2 := Ideal(a-1, b);
    A := Intersection(I1, I2);
    I3 := Ideal(b, c-1);
    I4 := Ideal(b-1, c);
    B := Intersection(I3, I4);
    I5 := Ideal(a, b, c-1);
    I6 := Ideal(b-1, a, c);
    I7 := Ideal(b, a-1, c);
    I8 := Ideal(b-1, a-1, c);
    C := Intersection(I5, I6, I7, I8);
    ReducedGBasis(A + B + C);
    [a, b+1, c]
    Jedinou možností je : A a C lžou, pokud B má pravdu.

    Obarvíme zeměpisnou mapu

    Můžeme obarvit státy na mapě s využitím pouhých tří barev tak, že každé dvě sousedící země mají odlišnou barvu?

    Use P ::= ZZ/(3)[x[1..6]];
    Define F(X)  Return X*(X-1)*(X+1);  EndDefine;
    VerticesEq := [ F(x[I]) | I In 1..6 ];
    Edges := [[1,2],[1,3],[2,3], [2,4], [2,5], [3,4], [3,6],
                [4,5], [4,6], [5,6]];
    EdgesEq := [ (F(x[A[1]])-F(x[A[2]]))/(x[A[1]]-x[A[2]])
                      |  A In Edges ];
    I := Ideal(VerticesEq) + Ideal(EdgesEq) + Ideal(x[1]-1, x[2]);
    ReducedGBasis(I);
    [x[2], x[1] - 1, x[3] + 1, x[4] - 1, x[6], x[5] + 1]
    Řešení lze formalizovat takto: proměnné x[1], x[2],... .., x[6] jsou státy, zatímco čísla -1, 0, 1 identifikují barvy, na příklad -1 znamená "zelená", 0 "modrá", a 1 je "červená". CoCoA najde možné zbarvení: Stát 1 = červený, stát 2 = modrý ... Stát 5 = zelený. Dostaneme:


    Heronův vzorec

    Můžeme vypočítat obsah trojúhelníka podle délky jeho stran?

    Use QQ[x[1..2],y,a,b,c,s];
    A := [x[1], 0];
    B := [x[2], 0];
    C := [ 0,   y];
    Hp := Ideal(a^2 - (x[2]^2+y^2),  b^2 - (x[1]^2+y^2),
                c   - (x[2]-x[1]),   2*s - c*y);
    E := Elim(x[1]..y,Hp);
    F := Monic(Comp(Gens(E),1));
    F;
    a^4 -2*a^2*b^2 +b^4 -2*a^2*c^2 -2*b^2*c^2 +c^4 +16*s^2
    Factor(F - 16*s^2);
    [[a + b + c, 1], [a + b - c, 1], [a - b + c, 1], [a - b - c, 1]]
    To znamená, že
    s^2 = -(1/16)(a+b+c)(a+b-c)(a-b+c)(a-b-c).
    Čtverec obsahu trojúhelníka se stranami a,b,c je p(p-a)(p-b)(p-c), kde p = 1/2(a+b+c) je polovina obvodu trojúhelníka. To je Heronův vzorec!

    Written by Alberto Damiano (thanks to Aleš Kocourek)
    Please send comments or suggestions to cocoa(at)dima.unige.it
    Last Update: 19 September 2011